{
  config,
  pkgs,
  lib,
  ...
}:

{

  services.wpaperd = {
    enable = true;
    settings = {
      default = {
        duration = "30m";
        mode = "center";
        sorting = "ascending";
        transition.hexagonalize = { };
      };

      any.path = pkgs.buildEnv {
        name = "nixos-artwork";
        paths = (
          pkgs.nixos-artwork.wallpapers
          |> lib.attrNames
          |> lib.remove "override"
          |> lib.remove "overrideDerivation"
          # removed because too bright
          |> lib.remove "binary-white"
          |> lib.remove "catppuccin-latte"
          |> lib.remove "moonscape"
          |> lib.remove "nineish-catppuccin-latte"
          |> lib.remove "nineish-catppuccin-latte-alt"
          |> lib.remove "nineish-solarized-light"
          |> lib.remove "nineish"
          |> lib.remove "simple-light-gray"
          |> map (name: "${pkgs.nixos-artwork.wallpapers.${name}}/share/backgrounds/nixos")
        );
      };
    };
  };

  programs.niri.settings.binds = with config.lib.niri.actions; {
    "Mod+Home".action = spawn (lib.getExe' pkgs.wpaperd "wpaperctl") "next";
  };

}