{
  npins,
  config,
  lib,
  pkgs,
  ...
}:

{

  options.common.configure.nix.enable = lib.mkEnableOption "sane nix defaults";

  imports =
    (lib.mkIf config.common.nix.enable [
      (import "${npins.lixModule}/module.nix" { lix = null; })
    ]).content;

  config = lib.mkIf config.common.configure.nix.enable (
    let
      NIXPKGS_PATH = lib.cleanSource npins.nixpkgs;
      NIXPKGS_UNSTABLE_PATH = lib.cleanSource npins.nixpkgsUnstable;

    in
    {
      nix = {
        package = pkgs.lix;
        nixPath = lib.mkForce [ "nixpkgs=${NIXPKGS_PATH}" ];
        channel.enable = lib.mkForce false;

        registry = {
          nixpkgs.to = {
            type = "path";
            path = NIXPKGS_PATH;
          };

          nixpkgsUnstable.to = {
            type = "path";
            path = NIXPKGS_UNSTABLE_PATH;
          };
        };

        settings = {
          nix-path = config.nix.nixPath;
          trusted-users = [ "@wheel" ];
          use-xdg-base-directories = true;
          experimental-features = [
            "flakes"
            "nix-command"
          ];
        };
      };

      environment.sessionVariables = {
        inherit NIXPKGS_PATH NIXPKGS_UNSTABLE_PATH;
      };
    }
  );

}