{
  tgcMaintainers,
  lib,
  fetchFromGitHub,
  buildNpmPackage,
  clientName ? "Phanpy",
  website ? "https://phanpy.social",
  defaultInstance ? "",
  defaultInstanceRegistrationUrl ? "",
  defaultLang ? "en",
  ...
}:

buildNpmPackage (finalAttrs: {
  pname = "phanpy";
  version = "2025.07.18.3f4b1a6";

  rev = "b74005d30721d55832b14a8f2e07bd918fdeb5c4";
  srcHash = "sha256-0OkH/XojM0W2oun797sNJqFrxNqFau1P+NECxCrib20=";
  npmDepsHash = "sha256-2a+5G0ENpjOvw+TuxEJrkabAB3uoQnaBQc7Nek7a/dw=";

  src = fetchFromGitHub {
    owner = "cheeaun";
    repo = "phanpy";
    hash = finalAttrs.srcHash;
    inherit (finalAttrs) rev;
  };

  env = {
    NODE_OPTIONS = "--openssl-legacy-provider";
    PHANPY_CLIENT_NAME = clientName;
    PHANPY_WEBSITE = website;
    PHANPY_DEFAULT_INSTANCE = defaultInstance;
    PHANPY_DEFAULT_INSTANCE_REGISTRATION_URL = defaultInstanceRegistrationUrl;
    PHANPY_DEFAULT_LANG = defaultLang;
  };

  installPhase = ''
    cp -r ./dist $out
  '';

  meta = {
    description = "A minimalistic opinionated Mastodon web client ";
    homepage = "https://github.com/cheeaun/phanpy";
    license = lib.licenses.mit;
    maintainers = [ tgcMaintainers.zaphyra ];
  };
})