{
  tgcMaintainers,
  fetchFromGitHub,
  buildGoModule,
  pkg-config,
  libxkbcommon,
  alsa-lib,
  wayland,
  vulkan-headers,
  xorg,
  libGL,
  lib,
  makeWrapper,
  ...
}:

buildGoModule (finalAttrs: {
  pname = "sointu";
  version = "unstable-2025-07-24";
  rev = "fe0106bb604f6f898091c6c7a042b97b9e2b2c48";
  srcHash = "sha256-N1Z9uccQXnrsLtyvUdb7IwPsDzziLeu2UYtndwWTQXA=";
  vendorHash = "sha256-gLDLKqu6k7/nwv6xHUE6MIYrbQFfVFAuUiMbLptcE5k=";

  src = fetchFromGitHub {
    owner = "vsariola";
    repo = finalAttrs.pname;
    hash = finalAttrs.srcHash;
    inherit (finalAttrs) rev;
  };

  nativeBuildInputs = [
    pkg-config
    makeWrapper
  ];

  buildInputs = [
    libxkbcommon
    alsa-lib
    wayland
    libGL
    vulkan-headers
    xorg.libX11
    xorg.libXcursor
    xorg.libXfixes
  ];

  env.CGO_ENABLED = 1;

  doCheck = false;

  proxyVendor = true;

  subPackages = [
    "cmd/sointu-compile"
    "cmd/sointu-play"
    "cmd/sointu-track"
  ];

  meta = with lib; {
    description = "Fork of 4klang that can target 386, amd64 and WebAssembly. Tools run on Windows, Mac & Linux";
    homepage = "https://github.com/vsariola/sointu";
    license = licenses.mit;
    maintainers = [ tgcMaintainers.zaphyra ];
  };

})